SetOptions[EvaluationNotebook[],CellContext->Notebook]

Some Examples of Planar Curves

By planar curves we mean a curve in the plane (ℝ^2). If we are given a paramatrization of such a curve we can use the function ParametricPlot to plot it. Here are some examples:

agnesi[a_][t_]:={2 a Tan[t],2 a ((Cos[t])^2)};

Manipulate[ParametricPlot[agnesi[a][t],{t,-Pi/2,Pi/2},PlotRange->{{-20,20},{-2a,2a}}],{{a,1,"parameter"},-1,20,Appearance->"Labeled"},SaveDefinitions->True]

From this picture it is not easy to see what is going on. Let’s look at it “dynamically” using Manipulate:

Manipulate[Show[{ParametricPlot[agnesi[1][t],{t,-Pi,Pi}],Graphics[{Red,PointSize[0.02],Point[agnesi[1][t]],Arrow[{agnesi[1][t],agnesi[1][t]+D[agnesi[1][s],s]/.s->t}]},Axes->True,PlotRange->{{-20,20},{-2,2}}]},ImageSize->Large],{{t,0,"t"},-Pi,Pi,Appearance->"Labeled"},SaveDefinitions->True]

We now see that the particle following the paramatric equation of motion first moves to the right with increasing speed and then at t=(π/2) reaches ∞, and then returns back from -∞.

Manipulate[Show[{ParametricPlot[agnesi[1][t],{t,0,2Pi}],Graphics[{Red,PointSize[0.01],Point[agnesi[1][t]],Arrow[{agnesi[1][t],agnesi[1][t]+Normalize[D[agnesi[1][s],s]/.s->t]}]},Axes->True,PlotRange->{{-10,10},{-2,2}}]}],{t,0,Pi,Appearance->"Labeled"},SaveDefinitions->True]

Parametric equations of some plane curves

Airyspiral

airyspiral[a][t] is a parametrized curve formed using Airy functions. Parametric equation:

airyspiral[a_][t_]:={a AiryAi[t],a AiryBi[t]}

ParametricPlot[airyspiral[1][t],{t,-20,1}]

archimedesspiral

archimedesspiral[n, a][t] is the spiral of Archimedes of radius a and degree n:

archimedesspiral[n_, a_][t_] :={a (t^(1/n)) Cos[t],a (t^(1/n)) Sin[t]}

Manipulate[ParametricPlot[archimedesspiral[n, 1][t],{t,0,12Pi},PlotRange->{{-5,5},{-5,5}}],{{n,1,"n"},1,10,1,Appearance->"Labeled"},SaveDefinitions->True]

astroid

astroid[a][t] is the parametrized curve whose implicit equation is (x^(2/3))+(y^(2/3))==(a^(2/3)). Parametric:.

astroid[a_][t_]:=a {Cos[t]^3,Sin[t]^3}

ParametricPlot[astroid[1][t],{t,0,2Pi}]

bicorn

bicorn[a][t] is a curve with two horns. Parametric equation: .

bicorn[a_][t_]:=a {Sin[t],((Cos[t]^2(Cos[t]+2))/(Sin[t]^2+3))}

ParametricPlot[bicorn[1][t],{t,0,2Pi}]

bow

bow[a][t] is a parametrized curve whose shape is a bow.

bow[a_][t_]:=a{Cos[t](1-Tan[t]^2),Sin[t](1-Tan[t]^2)}

ParametricPlot[bow[1][t],{t,0,2Pi}]

bowtie

bowtie[a, b][t] is a parametrized curve whose shape is a bowtie.

bowtie[a_,b_][t_]:={a Sin[t](Cos[t]^2+1),Cos[t](b+Sin[t]^2)}

Manipulate[ParametricPlot[bowtie[a,b][t],{t,0,2Pi}],{{a,1,"a"},0,2,Appearance->"Labeled"},{{b,0,"b"},0,2,Appearance->"Labeled"},SaveDefinitions->True]

bulletnose

bulletnose[a, b][t] is the parametric form of the curve whose implicit equation is a^2/x^2 - b^2/y^2 == 1.

bulletnose[a_,b_][t_]:={a Cos[t],b Cot[t]}

Manipulate[ParametricPlot[bulletnose[a,b][t],{t,0,2Pi}],{{a,3,"a"},0,3,Appearance->"Labeled"},{{b,1,"b"},0,3,Appearance->"Labeled"},SaveDefinitions->True]

cardioid

cardioid[a][t] is a cardioid or heart - shaped curve that is traced by a point on the circumference of a circle of radius 2*a rolling around a fixed circle of the same radius.

cardioid[a_][t_]:=2a {Cos[t](Cos[t]+1),Sin[t](Cos[t]+1)}

ParametricPlot[cardioid[1][t],{t,0,2Pi}]

cassini

cassini[a, b, pm1, pm2][t] is a parametrization of an oval of Cassini.The parameters pm1 and pm2 are plus or minus 1. The implicit equation is (x^2 + y^2 + a^2)^2 - b^4 - 4*a^2*x^2 == 0.

cassini[p_,q_,a_,b_][t_]:=p{Cos[t](Sqrt[q*Sqrt[a^4*(-Sin[2*t]^2) + a^2*Cos[2*t] + b^4]]),Sin[t]Sqrt[q Sqrt[b^4-a^4Sin[2t]^2+a^2 Cos[2t]]]}

ParametricPlot[cassini[1,1,1.99, 2 ][t],{t,0,2Pi}]

Manipulate[ParametricPlot[cassini[p,q,a,b][t],{t,0,2Pi}],{{p,1,"p"},{1->"1",-1->"-1"}},{{q,1,"q"},{1->"1",-1->"-1"}},{{a,1.99,"a"},0,2,Appearance->"Labeled"},{{b,2,"b"},0,2,Appearance->"Labeled"}]

catenary

catenary[a][t] is the curve formed by a perfectly flexible inextensible chain of uniform density hanging from two supports. Parametric equation {a cosh((t/a)),t}

catenary[a_][t_]:={a Cosh[(t/a)],t}

Manipulate[ParametricPlot[catenary[a][t],{t,-4,4}],{{a,-1,"a"},-1,1,Appearance->"Labeled",SaveDefinitions->True}]

cayleysextic

cayleysextic[a][t] is Cayley' s sextic curve. Parametric equation.

cayleysextic[a_][t_] :=4a{Cos[t/2]^4(2Cos[t]-1),Sin[3t/2]Cos[t/2]^3}

ParametricPlot[cayleysextic[1][t] ,{t,0,2Pi}]

Cartesian Equations

There are many curves for which parametric equations are not known. Sometiemes they can be described by a simple explicit equation, e.g. the parabola y= a (x^2)+b x +c. These can be plotted using the Plot function:

Manipulate[Plot[a (x^2)+b x +c, {x,-3,3}],{{a,1,"a"},-2,2,Appearance->"Labeled"},{{b,1,"b"},-2,2,Appearance->"Labeled"},{{c,1,"c"},-2,2,Appearance->"Labeled"},SaveDefinitions->True]

There are many other curves for which explicit equations are difficult or impossible to obtain. Many of them can be plotted using the ContourPlot function.

cassini[a_,b_][x_,y_]:=((((a^2)+(x^2)+(y^2)))^2)-4 (a^2) (x^2)-(b^4)

ContourPlot[cassini[2.01,2][x,y]==0,{x,-4,4},{y,-2,2}]

Manipulate[ContourPlot[cassini[a,b][x,y]==0,{x,-4,4},{y,-2,2}],{{a,2.01,"a"},-4,4,Appearance->"Labeled"},{{b,2.,"b"},-4,4,Appearance->"Labeled"},SaveDefinitions->True]

Curvature of a curve

Clear[tangent]

Let α: I -> (ℝ^n) be a smooth curve.  Then

We can use Norm and Normalize but if we work only with real curves it is useful to define new functions norm and normalize.

norm[v_?VectorQ]:=Sqrt[v.v]

normalize[v_?VectorQ]:=v/norm[v]

uTangent[α_?VectorQ,t_]:=normalize[D[α,t]]

uTangent[{x[t],y[t]},t]

uTangent is the unit tangent vector field to α. The curvature of α at t is defined as the “rate of turning” of uTangent, i.e.  ((Norm[((∂uTangent(α,t))/(∂t))])/(Norm[Tangent(α,t)]))

κ[α_,t_]:=(Sqrt[(((∂_({t}))uTangent[α,t].(∂_({t}))uTangent[α,t])/((∂_({t}))α.(∂_({t}))α))])

κ[{x[t],y[t]},t]

Simplify[κ[{x[t],y[t]},t],Element[_,Reals]]

If we write out the formula explicitely, the computation of curvature will be faster.

Clear[κ]

κ[α_,t_Symbol]:=(√(D[α,t].D[α,t] D[α,{t,2}].D[α,{t,2}]-(((D[α,t].D[α,{t,2}]))^2)))/(((D[α,t].D[α,t]))^(3/2))

For a curve given as a function :

κ[α_][t_]:=((Sqrt[(α'[t].α'[t]) (α''[t].α''[t])-(((α'[t].α''[t]))^2)])/(((α'[t].α'[t]))^(3/2)))

Simplify[κ[{x[t],y[t]},t],Element[_,Reals]]

Simplify[κ[{x[#],y[#]}&][t],Element[_,Reals]]

hypotrochoid[a_,b_,h_][t_]:={h Cos[((t (a-b))/b)]+(a-b) Cos[t],(a-b) Sin[t]-h Sin[((t (a-b))/b)]}

curve=ParametricPlot[hypotrochoid[5,1,2][t],{t,0,2Pi}]

κ[hypotrochoid[5,1,2][s],s]/.s->0.1

κ[hypotrochoid[5,1,2]][0.1]

Manipulate[Grid[{{Show[Graphics[{Red,PointSize[0.02],Point[hypotrochoid[5,1,2][t]]}],curve],Style[κ[hypotrochoid[5,1,2]][t],Red]}}],{t,0.,2Pi,Appearance->"Labeled"},SaveDefinitions->True]